home *** CD-ROM | disk | FTP | other *** search
/ Softdisk Supreme / Softdisk Supreme.iso / pc / DSK Files / 0-49 / SD008b.dsk / JURY.bas < prev    next >
BASIC Source File  |  2003-06-12  |  7KB  |  153 lines
  1. 10  REM  ***********************
  2. 11  REM  *                     *
  3. 12  REM  *       J U R Y       *
  4. 13  REM  *                     *
  5. 14  REM  *         B Y         *
  6. 15  REM  *                     *
  7. 16  REM  *       D O U G       *
  8. 17  REM  *    C O L L I N S    *
  9. 18  REM  *                     *
  10. 19  REM  *        5/7/82       *
  11. 20  REM  *                     *
  12. 21  REM  *                     *
  13. 22  REM  *         ALL         *
  14. 23  REM  *       RIGHTS        *
  15. 24  REM  *      RESERVED       *
  16. 25  REM  *                     *
  17. 26  REM  ***********************
  18. 27  REM 
  19. 28  REM 
  20. 1000  NORMAL : TEXT : HOME :D$ = "<CTRL-D>": PRINT D$;"IN#0": PRINT D$;"PR#0": GOTO 1450
  21. 1010  GET CH$: IF CH$ < > CHR$(89)  AND CH$ < > CHR$(78)  THEN 1010
  22. 1020  PRINT CH$: RETURN 
  23. 1030  RETURN 
  24. 1040  HOME : PRINT " #" TAB( 7)"SEX" TAB( 13)"AGE" TAB( 21)"RACE" TAB( 34)"CAREER": FOR X = 1 TO 39: PRINT "-";: NEXT : PRINT "": RETURN 
  25. 1050  REM 
  26. 1060  REM  SEX SELECTION
  27. 1070  REM 
  28. 1080 TN(X) = 0
  29. 1090 Y =  RND(65): IF Y >.5  THEN S$(X) = "  MALE": GOTO 1140
  30. 1100 S$(X) = "FEMALE":TN(X) = 2
  31. 1110  REM 
  32. 1120  REM  AGE SELECTION
  33. 1130  REM 
  34. 1140 Y =  RND(23) *100:A(X) = 20:TN(X) = TN(X) +5
  35. 1150  IF Y >10  THEN A(X) = 30:TN(X) = TN(X) +3
  36. 1160  IF Y >30  THEN A(X) = 40:TN(X) = TN(X) +2
  37. 1170  IF Y >50  THEN A(X) = 50:TN(X) = TN(X) +2
  38. 1180  IF Y >75  THEN A(X) = 60:TN(X) = TN(X) +3
  39. 1190  REM 
  40. 1200  REM  RACE SELECTION
  41. 1210  REM 
  42. 1220 Y =  RND(756) *100:R$(X) = "W.A.S.P.":TN(X) = TN(X) +7
  43. 1230  IF Y >25  THEN R$(X) = "   IRISH":TN(X) = TN(X) +3
  44. 1240  IF Y >40  THEN R$(X) = " ITALIAN":TN(X) = TN(X) +2
  45. 1250  IF Y >50  THEN R$(X) = "  JEWISH":TN(X) = TN(X) -1
  46. 1260  IF Y >55  THEN R$(X) = "  NORDIC":TN(X) = TN(X) +2
  47. 1270  IF Y >65  THEN R$(X) = "   BLACK":TN(X) = TN(X) -10
  48. 1280  IF Y >85  THEN R$(X) = "  SLAVIC":TN(X) = TN(X) +12
  49. 1290  IF Y >95  THEN R$(X) = " SPANISH":TN(X) = TN(X) -10
  50. 1300  REM 
  51. 1310  REM  JOB SELECTION
  52. 1320  REM 
  53. 1330  IF A(X) = 60  AND  RND(34) <.75  THEN J$(X) = "      RETIRED":TN(X) = TN(X) +10: GOTO 1390
  54. 1340 Y =  RND(87) *80:J$(X) = " PROFESSIONAL":TN(X) = TN(X) +5
  55. 1350  IF Y >10  THEN J$(X) = "CIVIL SERVICE":TN(X) = TN(X) +3
  56. 1360  IF Y >25  THEN J$(X) = "  BLUE COLLAR":TN(X) = TN(X) -1
  57. 1370  IF Y >55  THEN J$(X) = " WHITE COLLAR":TN(X) = TN(X) -1
  58. 1380  IF Y >70  THEN J$(X) = "   UNEMPLOYED":TN(X) = TN(X) -3
  59. 1390  RETURN 
  60. 1400  IF S$(X) = ""  THEN  FOR Y = 1 TO 39: PRINT " ";: NEXT Y: RETURN 
  61. 1410  IF X <10  THEN  PRINT " ";X;: GOTO 1430
  62. 1420  PRINT X;
  63. 1430  PRINT  TAB( 5);S$(X); TAB( 14);A(X); TAB( 17);R$(X); TAB( 27);J$(X);
  64. 1440  RETURN 
  65. 1450  DIM S$(13),A(13),R$(13),J$(13),TN(13),D$(13)
  66. 1460 CL = 12
  67. 1470  PRINT "DO YOU WANT INSTRUCTIONS (Y/N)": GOSUB 1010: IF CH$ = "Y"  THEN  GOSUB 2160
  68. 1480  FOR X = 1 TO 12:TN(X) = 0: NEXT 
  69. 1490  HOME 
  70. 1500  VTAB 12: HTAB 16: INVERSE : PRINT "WORKING": NORMAL 
  71. 1510  FOR X = 1 TO 12: GOSUB 1080: NEXT 
  72. 1520  GOSUB 1040
  73. 1530  FOR X = 1 TO 12: GOSUB 1400: PRINT "": NEXT 
  74. 1540 SJ = 0:CR = 0
  75. 1550  IF CL = 0  THEN  HOME : TEXT : PRINT "YOU HAVE NO CHALLENGES LEFT": PRINT "THE COMPUTER WILL FILL OUT THE JURY": PRINT "PRESS <RETURN> TO GET THE VERDICT": GET CH$: PRINT CH$: GOTO 1890
  76. 1560  FOR X = 1 TO 39: PRINT "-";: NEXT : PRINT ""
  77. 1570  POKE 34,17
  78. 1580  HOME : PRINT "DO YOU WANT TO MAKE A CHALLENGE (Y/N)": GOSUB 1010: IF CH$ = "N"  THEN  TEXT : HOME : GOTO 1950
  79. 1590  HOME : PRINT "HOW MANY CHALLENGES DO YOU WANT TO MAKE": PRINT "(YOU HAVE ";CL;" LEFT)": INPUT CH: IF CH >12  OR CH <1  THEN 1590
  80. 1600  IF CH >CL  THEN  HOME : PRINT "YOU ONLY HAVE ";CL;" CHALLENGES LEFT": FOR X = 1 TO 2000: NEXT X: GOTO 1590
  81. 1610  VTAB 16: INVERSE : PRINT "<CR> TO CHALLENGE,ARROW KEYS MOVE CURSOR";: NORMAL : FOR X = 1 TO 39: PRINT "-";: NEXT : PRINT ""
  82. 1620 WH = SJ +1: HOME :CL = CL -CH:P = CH: POKE  -16368,0
  83. 1630  VTAB WH +2 -(SJ): INVERSE :X = WH: GOSUB 1400: NORMAL 
  84. 1640  GET CH$: IF  ASC(CH$) <8  OR  ASC(CH$) >21  THEN 1640
  85. 1650 R =  ASC(CH$): PRINT ""
  86. 1660  IF R = 8  THEN  VTAB WH +2 -SJ: GOSUB 1400: PRINT " ":WH = WH -1: IF WH <SJ +1  THEN WH = 12
  87. 1670  IF R = 8  THEN 1630
  88. 1680  IF R < >13  AND R < >21  THEN 1660
  89. 1690  IF R = 21  THEN  VTAB WH +2 -SJ: GOSUB 1400: PRINT " ":WH = WH +1: IF WH >12  THEN WH = SJ +1
  90. 1700  IF R = 21  THEN 1630
  91. 1710 S$(WH) = "":P = P -1: VTAB WH +2 -SJ: FOR X = 1 TO 39: PRINT " ";: NEXT : PRINT "":WH = SJ +1
  92. 1720  IF P = 0  THEN 1740
  93. 1730  GOTO 1630
  94. 1740 SJ = 12
  95. 1750  FOR X = 1 TO 12: IF S$(X) = ""  THEN 1780
  96. 1760  NEXT 
  97. 1770  GOTO 1810
  98. 1780 SJ = SJ -1: FOR Y = X TO 11:S$(Y) = S$(Y +1):A(Y) = A(Y +1):R$(Y) = R$(Y +1):J$(Y) = J$(Y +1):TN(Y) = TN(Y +1): NEXT Y
  99. 1790  IF SJ = 12 -CH  THEN 1810
  100. 1800  IF X <12  THEN 1750
  101. 1810  IF SJ = 12  THEN  PRINT : TEXT : HOME : PRINT "YOU HAVE SEATED 12 JURORS": FOR X = 1 TO 1000: GOTO 1950
  102. 1820  TEXT : HOME : PRINT "YOU HAVE SEATED ";SJ;" JURORS": FOR X = 1 TO 1000: NEXT 
  103. 1830  FOR X = SJ +1 TO 12: GOSUB 1080: NEXT 
  104. 1840  GOSUB 1040: FOR X = SJ +1 TO 12: GOSUB 1400: PRINT "": NEXT 
  105. 1850 CR = SJ: GOTO 1550
  106. 1860  REM  
  107. 1870  REM  FILL OUT JURY
  108. 1880  REM 
  109. 1890  FOR X = SJ +1 TO 12: GOSUB 1080: NEXT 
  110. 1900  REM 
  111. 1910  REM  DETERMINE VERDICT
  112. 1920  REM 
  113. 1930  HOME 
  114. 1940  PRINT " THE FINAL SELECTIONS ARE :": PRINT : PRINT 
  115. 1950  GOSUB 1040: FOR X = 1 TO 12: GOSUB 1400: PRINT : NEXT X
  116. 1960  FOR X = 1 TO 39: PRINT "-";: NEXT X: PRINT 
  117. 1970  VTAB 20: PRINT " THIS IS THE FINAL JURY": PRINT "PRESS <RETURN> TO GET VERDICT";: GET A$: PRINT A$: HOME 
  118. 1980  REM   IF TN(X) IS < Z
  119. 1990  REM   THEN FIRST VERDICT IS
  120. 2000  REM  NOT GUILTY
  121. 2010  REM  IF AVERAGE OF TN(X)
  122. 2020  REM  IS < Z THEN FINAL 
  123. 2030  REM  VERDICT IS NOT GUILTY
  124. 2040  REM 
  125. 2050 Z =  RND(213) *31 +12
  126. 2060 T = 0: FOR X = 1 TO 12:T = T +TN(X): IF TN(X) <Z  THEN D$(X) = "NOT GUILTY !": NEXT : GOTO 2080
  127. 2070 D$(X) = "    GUILTY !": NEXT 
  128. 2080  PRINT " THE FIRST BALLOT CAME IN AS FOLLOWS"
  129. 2090  PRINT : FOR X = 1 TO 12: PRINT "JUROR #";X; TAB( 15);D$(X): NEXT 
  130. 2100  FOR X = 1 TO 2000: NEXT X
  131. 2110  IF (T/12) <Z  THEN FV$ = "NOT GUILTY !": GOTO 2130
  132. 2120 FV$ = "GUILTY !!!"
  133. 2130  PRINT : PRINT "THE JURY'S FINAL VERDICT IS ";: INVERSE : PRINT FV$: NORMAL 
  134. 2140  VTAB 23: PRINT " DO YOU WISH TO TRY ANOTHER CASE (Y/N)": GOSUB 1010: IF CH$ = "Y"  THEN  RUN 
  135. 2150  HOME : END 
  136. 2160  HOME : PRINT "  'JURY' IS A SIMULATION OF THE JURY"
  137. 2170  PRINT "SELECTION PROCESS. IT WAS DESIGNED TO"
  138. 2180  PRINT "SHOW THE RELATIONSHIP BETWEEN AGE ,RACE"
  139. 2190  PRINT ",SEX ,CAREER AND A JUROR'S VOTING TEN-"
  140. 2200  PRINT "DENCIES."
  141. 2210  PRINT : PRINT "  THE AGE ,RACE ,SEX AND CAREER OF EACH"
  142. 2220  PRINT "JUROR IS SELECTED RANDOMLY BUT THE "
  143. 2230  PRINT "AMOUNT OF EACH IS STATISTICALY CORRECT"
  144. 2240  PRINT "IN RELATION TO THE OTHERS. (I.E. MORE"
  145. 2250  PRINT "BLUE COLLAR WORKERS THEN PROFESSIONALS)."
  146. 2260  PRINT "  THE STATISTICS AND TENDENCIES CAME "
  147. 2270  PRINT "FROM VARIOUS BOOKS AND MAGAZINES."
  148. 2275  PRINT : PRINT " THE OBJECT IS AQUITTAL"
  149. 2280  PRINT : PRINT " WHEN CHALLENGING A JUROR USE THE ARROW"
  150. 2290  PRINT "KEYS TO POSITION THE CURSOR OVER THE"
  151. 2300  PRINT "DESIRED JUROR THEN PRESS THE <RETURN>"
  152. 2310  PRINT "KEY TO CHALLENGE HIM."
  153. 2320  VTAB 23: HTAB 7: PRINT "PRESS <RETURN> TO CONTINUE";: GET CH$: PRINT CH$: RETURN